TRC20 代幣合約範例的中文注釋

區塊鏈Blockchain andy 1年前 (2021-07-21) 633次浏览 已收录 0个评论 扫描二维码

TRC20 代幣合約範例的中文注釋

pragma solidity ^0.4.16;

interface tokenRecipient { 
	function receiveApproval(address _from, uint256 _value, address _token, bytes _extraData) external; 
}

contract TokenTRC20 {
    // 代幣的公共變數
    string public name;
    string public symbol;
    uint8 public decimals = 18;
    //強烈建議使用預設的 18位小數
    
    uint256 public totalSupply;

    // 建立一個存入所有餘額的陣列
    mapping (address => uint256) public balanceOf;
    mapping (address => mapping (address => uint256)) public allowance;

    // 在鏈上產生一個通知客戶端程式的公共事件
    event Transfer(address indexed from, address indexed to, uint256 value);

    // 通知客戶端燒掉多少代幣
    event Burn(address indexed from, uint256 value);

    /**
     * 建構函數
     *
     * 用合約的代幣供應量來初始化合約
     */
    function TokenTRC20(
        uint256 initialSupply,
        string tokenName,
        string tokenSymbol
    ) public {
        totalSupply = initialSupply * 10 ** uint256(decimals);  // 用小數的總量來更新代幣的總量
        balanceOf[msg.sender] = totalSupply;                // 把所有的代幣全部給建立者
        name = tokenName;                                   // 代幣名稱
        symbol = tokenSymbol;                               // 代幣符號
    }

    /**
     * 內部轉移,只能被這個合約呼叫
     */
    function _transfer(address _from, address _to, uint _value) internal {
	      // 防止轉移到 0x0 的地址,如果要燒掉代幣,就用 burn()
        require(_to != 0x0);
	      // 檢查傳送者是不是有足多的餘額
        require(balanceOf[_from] >= _value);
        // 溢位檢查
        require(balanceOf[_to] + _value >= balanceOf[_to]);
        // 儲存雙方餘額,以備未來判斷
        uint previousBalances = balanceOf[_from] + balanceOf[_to];
        // 從傳送者減掉代幣數量
        balanceOf[_from] -= _value;
        // 把代幣數量加到接收者
        balanceOf[_to] += _value;
        emit Transfer(_from, _to, _value);
	      // 使用統計來分析判斷你的代碼是不是有 Bug 
        assert(balanceOf[_from] + balanceOf[_to] == previousBalances);
    }

    /**
     * 轉移代幣
     *
     * 從你的帳號轉移 `_value` 數量的代幣,到`_to` 這個帳號
     *
     * @param _to 接收者地址
     * @param _value 代幣要轉移的數量
     */
    function transfer(address _to, uint256 _value) public {
        _transfer(msg.sender, _to, _value);
    }

    /**
     * 從其他地址轉移代幣
     *
     * 從 `_from` 轉移 `_value` 數量的代幣,到 `_to` 地址 
     *
     * @param _from 傳送者地址
     * @param _to 接收者地址
     * @param _value 代幣要轉移的數量
     */
    function transferFrom(address _from, address _to, uint256 _value) public returns (bool success) {
        require(_value <= allowance[_from][msg.sender]);     // 檢查是不是經過允許
        allowance[_from][msg.sender] -= _value;
        _transfer(_from, _to, _value);
        return true;
    }

    /**
     * 允許其他地址使用你的代幣
     *
     * 允許其他地址 `_spender` 使用你不多於 `_value` 數量的代幣
     *
     * @param _spender 允許使用你代幣的其他地址
     * @param _value 允許使用的最大代幣數量
     */
    function approve(address _spender, uint256 _value) public
        returns (bool success) {
        allowance[msg.sender][_spender] = _value;
        return true;
    }

    /**
     * 允許並通知其他地址使用你的代幣
     *
     * 允許其他地址 `_spender` 使用你不多於 `_value` 數量的代幣,並且通知合約
     *
     * @param _spender 允許使用你代幣的其他地址
     * @param _value 允許使用的最大代幣數量
     * @param _extraData 額外的信息發送到批准的合約
     */
    function approveAndCall(address _spender, uint256 _value, bytes _extraData)
        public
        returns (bool success) {
        tokenRecipient spender = tokenRecipient(_spender);
        if (approve(_spender, _value)) {
            spender.receiveApproval(msg.sender, _value, this, _extraData);
            return true;
        }
    }

    /**
     * 銷毀代幣
     *
     * 系統性不可復原的刪除 `_value` 數量的代幣
     *
     * @param _value 要燒掉的代幣數量
     */
    function burn(uint256 _value) public returns (bool success) {
        require(balanceOf[msg.sender] >= _value);   // 檢查傳送者的代幣是否足夠
        balanceOf[msg.sender] -= _value;            // 從傳送者扣掉代幣
        totalSupply -= _value;                      // 更新總量
        emit Burn(msg.sender, _value);
        return true;
    }

    /**
     * 從其他帳號銷毀代幣
     *
     * 系統性不可復原的從 `_from` 帳號刪除 `_value` 數量的代表
     *
     * @param _from 要刪除帳號的代幣
     * @param _value 要燒掉的代幣數量
     */
    function burnFrom(address _from, uint256 _value) public returns (bool success) {
        require(balanceOf[_from] >= _value);                // 檢查要刪除的帳號代幣是否足夠
        require(_value <= allowance[_from][msg.sender]);    // 檢查是否被允許
        balanceOf[_from] -= _value;                         // 從帳號刪除
        allowance[_from][msg.sender] -= _value;             // 從傳送者裡面的允許數量裡刪除
        totalSupply -= _value;                              // 更新總量
        emit Burn(_from, _value);
        return true;
    }
}

波場Tron 的 TRC20 代幣很像以太坊 Ethereum 的 ERC20 代幣,當然不同的區塊鏈有不同的機制,兩者不完全相同。

沒有開發過 Token 合約的小伙伴,稍微注意一下所謂小點數 Decimal 的用法。一個簡單的想像,比如 decimal 等於 6 的意思就是把小數點後第六位當成個位數 。這個範例裡面的 decimal 的預設值是 18 ,就是把小數點後第18位當成個位數。所以 1 個 token 的就是 100000000000000000 。

參考
https://tronprotocol.github.io/documentation-en/contracts/trc20/


神隊友學長Andy , 版权所有丨如未注明 , 均为原创丨本网站采用BY-NC-SA协议进行授权
转载请注明原文链接:TRC20 代幣合約範例的中文注釋
喜欢 (0)
[[email protected]]
分享 (0)
andy
关于作者:
中年大叔,打拼 like young students.
发表我的评论
取消评论
表情 贴图 加粗 删除线 居中 斜体 签到

Hi,您需要填写昵称和邮箱!

  • 昵称 (必填)
  • 邮箱 (必填)
  • 网址